Excel programba tudtok képletetben segíteni?

Az A munkalap C1 cellájába az alább függvényt kell írni.

=HA(B1="bizonyos szöveg";Bmunkalap.C1;"")

A D1 cellába ugyanezt, csak D1-gyel.

Érthetőbb lenne, ha mintát közölnél, vagy fényképet. Sokan vannak, akik tudnának megoldást, bizonyára azért nem írnak, mert nemigen érthető pontosan, hogy mit szeretnél.

Nagy esély van rá, hogy nem úgy van, ahogy kihámozom az írásaidból, de nem nagy időveszteség megírnom.

• „B” munkalap A, B és C oszlopaiban adatok vannak; egy-egy sorban, összetartozók.

Pl.:

│alma│magas készlet│180 Ft/kg│

│körte│magas készlet│220 Ft/kg│

│eper│elfogyott│650 Ft/kg│

│barack│alacsony készlet│350 Ft/kg│

• „A” munkalap B1 cellájába beírom, például, hogy eper.

• Azt szeretném, hogy „A” munkalap C1 cellájában megjelenjen az eperhez a „B” munkalap B oszlopában az eperhez tartozó elfogyott, illetve az „A” munkalap D1 cellájában megjelenjen a „B” munkalap C oszlopában az eperhez tartozó 350 Ft/kg.

Ha így van, akkor FKERES függvény erre van kitalálva.

„A” munkalap C1 cellájába beírom, hogy

=FKERES(B1;B!A1:B!C1000;2;HAMIS)

„A” munkalap D1 cellájába beírom, hogy

=FKERES(B1;B!A1:B!C1000;3;HAMIS)

Ha B1-be olyan lenne írva, ami nem található, akkor #HIÁNYZIK jelenik meg C1; D1 cellákban.

Elegánsabb, ha „A” munkalap C1 cellájába ez kerül:

=HA(NINCS(FKERES(B1;B!A1:B!C1000;2;HAMIS));B1&" nincs.";FKERES(B1;B!A1:B!C1000;2;HAMIS))

↑

(Gondolom, a GYK több sorba töri, de elejétől végéig kijelölve, bemásolható az Excelbe.

A” munkalap D1 cellájába pedig ez kerül:

=HA(NINCS(FKERES(B1;B!A1:B!C1000;3;HAMIS));"";FKERES(B1;B!A1:B!C1000;3;HAMIS))

Így néz ki:

[link]

[link]

[link]

[link]

[link]

Ha nem találtam ki, mit kérdeztél – és a válasz-szünet alapján más sem -, akkor próbáld valahogy bemutatni konkrétan, hogy mit szeretnél.

Több találat megjelenítésére az én javaslatom a HOL.VAN függvény használata.

Azt adja meg, hogy a keresett érték, adott oszlop megadott cellatartományán belül, hányadik sorban fordul elő.

Ha a keresett érték „G6” cellában van, akkor a függvény

• G1:G25 keresési tartomány esetén 6-ot ad vissza,

• G5:G25 keresési tartomány esetén 2-őt ad vissza,

• G6:G25 keresési tartomány esetén 1-et ad vissza.

Azt kell tenni, hogy a következő keresést az előző találat utáni sortól kell kezdeni. Persze, ki kell számítani, hogy az adott tartomány valahányadik sorában történő találat a teljes oszlop hányadik sora.

Az összetettség miatt segédoszlopokat használok. Ha ezek zavarók, akkor láthatatlanná lehet tenni ezeket.

• a betűszínt olyanra kell választani, mint a háttérszín, vagy

• az oszlopszélességet 0-ra kell állítani, vagy

• a Formátum → Oszlop → Elrejtés a megoldás.

Az bonyolítja a képleteket, hogy eltünteti a különböző üzeneteket: #HIÁNYZIK, #HIVATKOZÁS stb. Vagy hasznos értékek vannak a cellákban, vagy üresek lesznek.

A „B” munkalap ilyen lett: [link]

► A m ű k ö d é s ilyen:

„A” munkalapon I1 mezőbe írtam, hogy hányas sorig keressen a „B” lapon.

Ez a szám nagyobb, jóval nagyobb is lehet, mint a ténylegesen használt sorok száma. Legalább az utolsó sor száma legyen. Az nem gond, ha vannak közben üres sorok is.

a) „A” munkalapon B1 mezőbe írás: barack.

C és D oszlopokban megjelennek a hozzátartozó adatok, 5-ször, mert ennyiszer van a „B” lapon.

E oszlopban megjelenítettem, hogy a „B” lap mely soraiban találta meg.

Az I-O oszlopok a segédoszlopok.

[link]

Az I-O oszlopoknál fehér betűszínt választottam: [link]

b) „A” munkalapon B1 mezőbe írás: sín.

Egyszer van a „B” lapon. [link]

c) „A” munkalapon B1 mezőbe írás: török.

Egyszer sincs a „B” lapon. [link]

► A mezőkbe írt k é p l e t e k :

J1: ="B!A"&I1

K1: =HA(N1<>"";"B!A"&1;"")

L1: =HA(N1<>"";HOL.VAN($B$1;INDIREKT(K1):INDIREKT($J$1);HAMIS);"")

M1: =L1

N1 = =HA($O$1>0;1;"")

O1: =DARABTELI(B!A1:INDIREKT(J1);B1)

K2: =HA(N2<>"";"B!A"&M1+1;"")

L2: =HA(N2<>"";HOL.VAN($B$1;INDIREKT(K2):INDIREKT($J$1);HAMIS);"")

M2: =HA(N2<>"";SZUM($L$1:L2);"")

N2: =HA(N1<>"";HA($O$1>=N1+1;N1+1;"");"")

K2 L2 M2 és N2 közösen kijelölve, jobb alsó saroknál megjelenő +-szal lehúzni annyi sorig, amennyi a várható találatok száma egy-egy beírásnál. Akár ráhagyással, akár az Excel tábla utolsó soráig.

C1: =HA(N1<>"";INDIREKT("B!B"&M1);"")

D1: =HA(N1<>"";INDIREKT("B!C"&M1);"")

E1: =HA(N1<>"";"("&M1&".)";"")

C1 D1 E1 közösen kijelölve, jobb alsó saroknál megjelenő +-szal lehúzni annyi sorig, amennyi a várható találatok száma egy-egy beírásnál. Akár ráhagyással, akár az Excel tábla utolsó soráig.

E oszlopot kijelölni és a jobbra igazításra kattintani.

A képletek innen kimásolhatók, beilleszthetők a cellákba.

Ha itt valamelyik megtörik, akkor az elejétől végéig kijelölhető, törés nélkül kerül a cellába.

Remélem, nem maradt ki semmi szükséges, illetve, hogy nem írtam el.

(Az Excelnél egyszerűbb volt, mert ilyen esetekben egyből látszik, ha valami hiányzik, vagy rossz.)

A HOL.VAN keresési értékénél lehet joker-karaktereket (* ?) is használni, akkor szövegrészletre is lehet keresni. (Nem úgy tűnt, hogy a kérdéses feladatnál ez szükséges.)

Annyi gondot okozhat a HOL.VAN függvény, hogy nem különbözteti meg a kis- és nagybetűket.

Lehet, hogy más ír számodra kedvezőbb megoldást. Működni, éppen, ez is működik.